Pomoc przy wyświetlaczach 7seg...

maxd89pl · Post autor: **maxd89pl** » 25 kwie 2017, 16:06

Witam, timer ma odliczać w dół, pouzupełniałem to o czym mówiłeś, trochę dopisałem kodu i większość skomentowałem, i teraz w miarę to działa. Obsługę multipleksacji mam stąd .
a program na tą chwile wygląda tak:

Code: [Zaznacz cały] [Rozwiń/Zwiń]

$regfile = "m328pdef.dat"
$crystal = 8000000
$hwstack = 64
$swstack = 64
$framesize = 128
Config Portd = Output
Config Portb.0 = Output
Config Portb.1 = Output
Config Portb.2 = Output
Config Portb.3 = Output
Config Pinc.0 = Input
Config Pinc.1 = Input
Config Pinc.2 = Input
Portc.0 = 1
Portc.1 = 1
Portc.2 = 1
Portb.0 = 0
Portb.1 = 0
Portb.2 = 0
Portb.3 = 0
Portd = 255
W1 Alias Portb.0
W2 Alias Portb.1
W3 Alias Portb.2
W4 Alias Portb.3
Prz1 Alias Pinc.0
Prz2 Alias Pinc.1
Enter Alias Pinc.2
Segmenty Alias Portd
Declare Sub Dec2bcd(byval Liczba As Byte , Byval Pozycja_wysw As Byte , Byref Tab() As Byte)
Dim s1 as Byte
Dim m1 as byte
Dim Sekundy As Byte
Dim Minuty as byte
Dim Wyswietlacz As Byte
Dim Tablica(4) As Byte
Dim Kr1 as Bit
Dim Kr2 as Bit
Dim Kr3 as Bit
Dim Kr4 as Bit
Dim f_Odej as Bit
Dim f_Dodaj as Bit
Dim Startuj as bit
dim 1_sek as Word
Dim Menu as Byte
Dim 8msek as Byte
Dim f_timer2 as bit
Config Timer0 = Timer , Prescale = 256
Config TIMER2 = Timer , Prescale = 256
On Ovf0 Przerwanie
On Timer2 Odmierz_1s
Load Timer0 = 65
Load Timer2 = 250
Enable Ovf0
Enable Timer2
Enable Interrupts
s1 = 0
m1 = 0
Sekundy = 0
Startuj = 0
Menu = 1
8msek = 0
Stop timer2
Do
Select Case Menu
Case 1:
If f_Dodaj = 0 Then
if Prz1 = 0 then ' Jeśli przycisk wciśnięty, czekaj 15ms(drgania styku) sprawdz ponownie przycisk, jeśli przyciśnięty to:
waitms 15
If Prz1 = 0 Then
s1 = s1 + 1 ' zwiększ o 1 zmienną s1
gosub Wyswietl
if s1 = 60 Then ' jeśli zmienna s1 dobije do 60 to
m1 = m1 + 1 ' zwiększ o 1 zmienną m1
s1 = 0 ' wyzeruj zmienną s1
gosub Wyswietl ' przejdz do podprogramu, by przekazać zmienne s1 i m1 do zmiennych Sekundy i Minuty, a następnie je wyświetlić
end if
waitms 30 ' opuźnienie 30ms przycisku
end if
End if
End if
if f_Odej = 0 then ' flaga pomocnicza, przy wartości zmiennych s1 = 0 i m1 = 0, wyłącza obsługe przycisku, uniemożliwiając dalsze odejmowanie
if Prz2 = 0 then ' jeśli wcisznięty
waitms 15 ' drganie styków
If Prz2 = 0 Then ' ponownie jeśli wciśnięty to:
s1 = s1 - 1 ' zmniejsz zmienną s1 o 1
gosub Wyswietl ' idz to wyświetlić
If m1 > 0 Then
' jeśli wartość minut jest większa niż 0 a sekund równa się 0 to:
If s1 = 0 Then
m1 = m1 - 1 ' zmniejsz minuty o 1
s1 = 60 ' a sekundy ustaw na 60
end if
waitms 30 ' opuźnienie przycisku
end if
end if
End if
end if
if Enter = 0 Then ' jeśli przycisk enter przyciśnięty to:
waitms 15 ' drganie styków
if Enter = 0 Then ' jeśli dalej wciśnięty to
Incr Menu ' zwiększ menu o 1 przechodząc do następnej funkcji menu z odliczaniem i bez obsługi przycisków
Bitwait Enter , Set ' ale poczekaj zanim powróci stan wysoki
end if
End if
If m1 > 0 Then ' zapalanie kropki gdy min większe od 0
Set Kr2
else
Reset Kr2
End if
If m1 = 0 then ' jeśli minuty są równe 0 i sekundy też 0 to:
If s1 = 0 Then
f_Odej = 1
' przestaw flagę od przycisku odejmowania co by go wyłączyć, albo nie jeśli główny warunek nie zostanie spełniony
else
f_Odej = 0
End if
end if
If m1 = 15 then ' jeśli minuty mają wartość 15 i sekundy 0 to: (ustawiłem na 15, bo przy testowaniu nie chciało mi się czekać do 30)
If s1 = 0 then
s1 = 0 ' zeruj minuty i sekundy
m1 = 0 ' idz to wyświetlić
gosub Wyswietl
End if
End if
Case 2: ' następna fukncja menu uruchamiana przyciskiem enter, odliczanie w dół bez już obsługi przycisków plus i minus
If f_timer2 = 0 then ' flaga pomocnicza zezwalająca na start timer2
Start timer2
else
Stop Timer2
End if
If m1 = 0 then ' jeśli sekundy i minuty dobiją do zera to:
If s1 = 0 Then
set f_timer2 ' resetowanie flagi i stop timer2
End if
end if
If m1 > 0 Then 'zapalanie kropki gdy min większe od 0
Set Kr2
else
Reset Kr2
End if
if Enter = 0 Then ' jeśli przycisk enter przyciśnięty to:
waitms 15 ' drganie styków
if Enter = 0 Then ' jeśli dalej wciśnięty to
toggle f_timer2 ' pauza lub wznowienie odliczania
Bitwait Enter , Set ' ale poczekaj zanim powróci stan wysoki
end if
End if
End Select
Loop
End 'end program
'**************************************************************
Wyswietl: ' podprogram wyświetlania, zmienne s1 i m1 przekazywane do zmiennych Sekundy i Minuty, a następnie multipleksowane na wyś. LED
Sekundy = s1
Dec2bcd Sekundy , 3 , Tablica(1)
Minuty = m1
Dec2bcd Minuty , 1 , Tablica(1)
return
Odmierz_1s: ' podprogram obliczania 1 sek
Load Timer2 = 250
Incr 8msek
if 8msek = 125 then
8msek = 0
s1 = s1 - 1
gosub Wyswietl
If m1 > 0 Then
If s1 = 0 Then
m1 = m1 - 1
s1 = 59
end if
end if
end if
Return
Przerwanie:
Load Timer0 , 65
Incr Wyswietlacz
If Wyswietlacz = 5 Then
Wyswietlacz = 1
End If
Select Case Wyswietlacz
Case 1:
W4 = 1
Segmenty = Lookup(tablica(1) , Kody7seg)
Portd.7 = Kr1
W1 = 0
Case 2:
W1 = 1
Segmenty = Lookup(tablica(2) , Kody7seg)
Portd.7 = Kr2
W2 = 0
Case 3:
W2 = 1
Segmenty = Lookup(tablica(3) , Kody7seg)
Portd.7 = Kr3
W3 = 0
Case 4:
W3 = 1
Segmenty = Lookup(tablica(4) , Kody7seg)
Portd.7 = Kr4
W4 = 0
End Select
Return
'************************************************************
Sub Dec2bcd(byval Liczba As Byte , Byval Pozycja_wysw As Byte , Byref Tab() As Byte)
Local Pomocnicza1 As Byte
Local Pomocnicza2 As Byte
Pomocnicza1 = Makebcd(liczba)
Pomocnicza2 = Pomocnicza1 And &B00001111
Tablica(pozycja_wysw + 1) = Pomocnicza2
Shift Pomocnicza1 , Right , 4
Pomocnicza2 = Pomocnicza1 And &B00001111
Tablica(pozycja_wysw) = Pomocnicza2
End Sub
Kody7seg:
Data &B00111111 , &B00000110 , &B01011011 , &B01001111 , &B01100110, '---> 0 , 1 , 2 , 3 , 4
Data &B01101101 , &B01111101 , &B00000111 , &B01111111 , &B01101111 '---> 5 , 6 , 7 , 8 , 9
' dp , g , f , e , d , c , b , a

docelowo w kodzie będę musiał zmienić wykrywanie przycisków z 0 na 1 gdyż chcę użyć dotykowych przycisków atmela at42 1010 a tam stanem aktywnym jest 1. Bawiłem się też timerem i jak ustawiłem preskaler na 1024 i wartoś początkową timera na 77 to wyświetlacze mrugają.
Co dziwne nie rozumiem pewnej rzeczy czym się różni zapis

Code: [Zaznacz cały] [Rozwiń/Zwiń]

Load Timer0 , 65

a tym

Code: [Zaznacz cały] [Rozwiń/Zwiń]

Load Timer0 = 65

, bo przy tym pierwszym działa wszystko ok a z znakiem = wyświetlacze mrugają.

Następny problem to gdy odlicza sekundy w dół na wyświetlaczu widzę 02 -> 01 -> 00 -> 58 ->57 gdzieś ginie 59

Noi na koniec doszedłem do wniosku po twojej sugestii, że przerobie program tak by jednym przyciskiem(minusem) zmieniać minuty a drugi (plusem) zmieniać sekundy, bo tak jak mówisz w poprzedniej wersji by ustawić na 20min strasznie długo trzeba było trzymać przycisk.

niveasoft · Post autor: **niveasoft** » 25 kwie 2017, 18:18

Musisz używać jakiegoś starego Bascom`a bo nowsze nie pozwalają już na taki zapis i zgłoszą błąd.
Prawidłowe są tylko zapisy "Load TIMERx , Wartość" , albo, bez LOAD, "TIMERx = Wartość"

W dużym uproszczeniu Timery liczą "w górę" do swojego maksimum. Dla takiego TIMER0 i TIMER2 maksimum to 255
TIMER = Wartość oznacza, że do Timera wpisujesz już jakąś wstępna wartość. Kiedy wpiszesz 100 to Timer liczy od 100 do 255, czyli będzie liczył 155 ticków. Wtedy sam musisz policzyć co wpisać do Timera żeby Ci odliczył tyle ile chcesz.

Kiedy chcesz by liczył określoną liczbę ticków nie musisz tego liczyć na piechotę. Kiedy użyjesz funkcji LOAD to program sam odejmie od maksimum określona liczbę ticków i resztę wpisze do Timera.

Na przykład chcesz by Timer odliczył 100 ticków to piszesz Load TIMERx, 100 a tak naprawdę procesor wpisze do Timera 155.
Timer zacznie liczyć od 155 i jak dojedzie do 255 to będzie akurat sto ticków.

Kiedy piszesz Load TIEMR0, 65 to procesor wpisuje do Timera 190 (255-65)
Możesz to sprawdzić pisząc Timer = 190. Efekt będzie identyczny.

maxd89pl · Post autor: **maxd89pl** » 25 kwie 2017, 20:05

niveasoft pisze: ↑
25 kwie 2017, 18:18
Musisz używać jakiegoś starego Bascom`a bo nowsze nie pozwalają już na taki zapis i zgłoszą błąd.
Prawidłowe są tylko zapisy "Load TIMERx , Wartość" , albo, bez LOAD, "TIMERx = Wartość"

Widzisz teraz to ja wiem o co biega.

Zmieniłem te przyciski teraz, że jednym się zmienia minuty a drugim sekundy, dodałem troche animacji na początek programu i gdy odliczanie dobiegnie do końca, ale znowu się wszystko krzaczy menu mam na select case i gdy program startuje od włączenia zasilania to jest ok, czyli 0000 ale po ustawieniu czasu case 2 , później po odliczaniu case 3 i animacji po skonczeniu odliczania w case 4 i w niej jak nacisne przycisk enter to wracamy do case 2 i zamiast na wyświetlaczu być 0000 to jest 95 w sekundach nie wiem skąd. Najlepiej zobacz na film, który tłumaczy chyba wszystko, bo tak opisać to trudne

Może znalazł byś troszkę czasu przeanalizować ten kod i wskazać mi potencjalne babole głownie te obliczenia na zmiennych

Mój brudnopis:

Code: [Zaznacz cały] [Rozwiń/Zwiń]

$regfile = "m328pdef.dat"
$crystal = 8000000
$hwstack = 64
$swstack = 64
$framesize = 128
Config Portd = Output
Config Portb.0 = Output
Config Portb.1 = Output
Config Portb.2 = Output
Config Portb.3 = Output
Config Pinc.0 = Input
Config Pinc.1 = Input
Config Pinc.2 = Input
Portc.0 = 1
Portc.1 = 1
Portc.2 = 1
Portb.0 = 1
Portb.1 = 1
Portb.2 = 1
Portb.3 = 1
'Portd = 255
W1 Alias Portb.0
W2 Alias Portb.1
W3 Alias Portb.2
W4 Alias Portb.3
Prz1 Alias Pinc.0
Prz2 Alias Pinc.1
Enter Alias Pinc.2
Segmenty Alias Portd
Declare Sub Dec2bcd(byval Liczba As Byte , Byval Pozycja_wysw As Byte , Byref Tab() As Byte)
Dim s1 as Byte
Dim m1 as byte
Dim Sekundy As Byte
Dim Minuty as byte
Dim Wyswietlacz As Byte
Dim Tablica(4) As Byte
Dim Kr1 as Bit
Dim Kr2 as Bit
Dim Kr3 as Bit
Dim Kr4 as Bit
Dim f_Odej as Bit
Dim f_Dodaj as Bit
Dim Startuj as bit
dim 1_sek as Word
Dim Menu as Byte
Dim 8msek as Byte
Dim f_timer2 as bit
Dim S_time as Bit
Dim restart as Byte
Config Timer0 = Timer , Prescale = 256
Config TIMER2 = Timer , Prescale = 256
'On Ovf0 Przerwanie
stop timer0
On Timer2 Odmierz_1s
Load Timer0 = 65
Load Timer2 = 250
Enable Ovf0
Enable Timer2
Enable Interrupts
s1 = 0
m1 = 0
Sekundy = 0
Startuj = 0
Menu = 1
8msek = 0
1_sek = 0
Stop timer2
Do
Select Case Menu
Case 1:
reset w1
Portd = &B01101101
waitms 400
set w1
reset w2
Portd = &B01111001
waitms 400
set w2
reset w3
Portd = &B01111100
waitms 400
set w3
reset w4
Portd = &B01110111
waitms 400
set w4
incr Menu
On Ovf0 Przerwanie
start timer0
Case 2:
stop timer2
f_timer2 = 1
start timer0
' if m1 > 0 then
'if s1 = 0 then
' s1 = 60
' else
' s1 = 0
'end if
'end if
if Prz1 = 0 then ' Jeśli przycisk wciśnięty, czekaj 15ms(drgania styku) sprawdz ponownie przycisk, jeśli przyciśnięty to:
waitms 15
If Prz1 = 0 Then
s1 = s1 + 1 ' zwiększ o 1 zmienną s1
gosub Wyswietl
if s1 = 60 Then ' jeśli zmienna s1 dobije do 60 to
s1 = 0 ' wyzeruj zmienną s1
gosub Wyswietl ' przejdz do podprogramu, by przekazać zmienne s1 i m1 do zmiennych Sekundy i Minuty, a następnie je wyświetlić
end if
waitms 100
end if
End if
if Prz2 = 0 then ' jeśli wcisznięty
waitms 15 ' drganie styków
If Prz2 = 0 Then ' ponownie jeśli wciśnięty to:
m1 = m1 + 1 ' zmniejsz zmienną s1 o 1
gosub Wyswietl ' idz to wyświetlić
If m1 = 30 Then
' jeśli wartość minut jest większa niż 0 a sekund równa się 0 to:
m1 = 0
end if
waitms 100 ' opuźnienie przycisku
end if
End if
if Enter = 0 Then ' jeśli przycisk enter przyciśnięty to:
waitms 15 ' drganie styków
if Enter = 0 Then ' jeśli dalej wciśnięty to
Incr Menu ' zwiększ menu o 1 przechodząc do następnej funkcji menu z odliczaniem i bez obsługi przycisków
Bitwait Enter , Set ' ale poczekaj zanim powróci stan wysoki
end if
End if
If m1 > 0 Then ' zapalanie kropki gdy min większe od 0
Set Kr2
else
Reset Kr2
End if
Case 3: ' następna fukncja menu uruchamiana przyciskiem enter, odliczanie w dół bez już obsługi przycisków plus i minus
If f_timer2 = 0 then ' flaga pomocnicza zezwalająca na start timer2
Start timer2
else
Stop Timer2
End if
If m1 = 0 then ' jeśli sekundy i minuty dobiją do zera to:
If s1 = 0 Then
set f_timer2
menu = 4 ' resetowanie flagi i stop timer2
End if
end if
If m1 > 0 Then 'zapalanie kropki gdy min większe od 0
Set Kr2
else
Reset Kr2
End if
if Enter = 0 Then ' jeśli przycisk enter przyciśnięty to:
waitms 15 ' drganie styków
if Enter = 0 Then ' jeśli dalej wciśnięty to
toggle f_timer2 ' pauza lub wznowienie odliczania
Bitwait Enter , Set ' ale poczekaj zanim powróci stan wysoki
end if
End if
Case 4:
if enter = 0 then
menu = 2
bitwait enter , set
's1 = 0
'sekundy = 0
'm1 = 0
'minuty = 0
end if
stop timer0
reset w1
reset w2
reset w3
reset w4
Portd = &B00000001
waitms 50
Portd = &B00000010
waitms 50
Portd = &B00000100
waitms 50
Portd = &B00001000
waitms 50
Portd = &B00010000
waitms 50
Portd = &B00100000
waitms 50
Portd = &B01000000
waitms 50
End Select
Loop
End 'end program
'**************************************************************
Wyswietl: ' podprogram wyświetlania, zmienne s1 i m1 przekazywane do zmiennych Sekundy i Minuty, a następnie multipleksowane na wyś. LED
Sekundy = s1
Dec2bcd Sekundy , 3 , Tablica(1)
Minuty = m1
Dec2bcd Minuty , 1 , Tablica(1)
return
Odmierz_1s: ' podprogram obliczania 1 sek
Load Timer2 = 250
Incr 8msek
if 8msek = 125 then
8msek = 0
s1 = s1 - 1
gosub Wyswietl
If m1 > 0 Then
If s1 = 1 Then
m1 = m1 - 1
s1 = 60
end if
end if
end if
Return
Przerwanie:
Load Timer0 , 65
Incr Wyswietlacz
Incr 1_sek
If Wyswietlacz = 5 Then
Wyswietlacz = 1
End If
If 1_sek = 481 then
1_sek = 0
Incr restart
end if
Select Case Wyswietlacz
Case 1:
W4 = 1
Segmenty = Lookup(tablica(1) , Kody7seg)
Portd.7 = Kr1
W1 = 0
Case 2:
W1 = 1
Segmenty = Lookup(tablica(2) , Kody7seg)
Portd.7 = Kr2
W2 = 0
Case 3:
W2 = 1
Segmenty = Lookup(tablica(3) , Kody7seg)
Portd.7 = Kr3
W3 = 0
Case 4:
W3 = 1
Segmenty = Lookup(tablica(4) , Kody7seg)
Portd.7 = Kr4
W4 = 0
End Select
Return
'************************************************************
Sub Dec2bcd(byval Liczba As Byte , Byval Pozycja_wysw As Byte , Byref Tab() As Byte)
Local Pomocnicza1 As Byte
Local Pomocnicza2 As Byte
Pomocnicza1 = Makebcd(liczba)
Pomocnicza2 = Pomocnicza1 And &B00001111
Tablica(pozycja_wysw + 1) = Pomocnicza2
Shift Pomocnicza1 , Right , 4
Pomocnicza2 = Pomocnicza1 And &B00001111
Tablica(pozycja_wysw) = Pomocnicza2
End Sub
Kody7seg:
Data &B00111111 , &B00000110 , &B01011011 , &B01001111 , &B01100110, '---> 0 , 1 , 2 , 3 , 4
Data &B01101101 , &B01111101 , &B00000111 , &B01111111 , &B01101111 '---> 5 , 6 , 7 , 8 , 9
' dp , g , f , e , d , c , b , a

niveasoft · Post autor: **niveasoft** » 25 kwie 2017, 20:08

Napisałem to przy kubku kawy.
Obecnie nie pisze już tak programów, ale nie chciałem zbyt daleko odbiec od Twojego kodu tak byś mógł z tego coś wyciągnąć.
Opisałem go jako tako bo muszę wracać do swoich zadań. Kod możesz przerobić/rozwinąć.

Powinien liczyć dobrze

Code: [Zaznacz cały] [Rozwiń/Zwiń]

$regfile = "m328pdef.dat"
$crystal = 8000000
$hwstack = 64
$swstack = 64
$framesize = 128
' PO WŁĄCZENIU PROGRAM WYŚWIETLA TYLKO DWA ZERA
' KIEDY WCIŚNIESZ RAZEM PLUS I MINUS TO ZEGAR USTAWI SIĘ NA
' 30min i 00sec
' KRÓTKIE WCIŚNIĘCIE ENTER URUCHAMIA BĄDŹ ZATRZYMUJE ODLICZANIE
' OCZYWIŚCIE MOŻNA SAMEMU USTAWIĆ ŻĄDANY CZAS PLUS/MINUS
Config Portd = Output : Portd = 255 : Segmenty Alias Portd
'anody wyswietlaczy
Config Portb.0 = Output : W1 Alias Portb.0
Config Portb.1 = Output : W2 Alias Portb.1
Config Portb.2 = Output : W3 Alias Portb.2
Config Portb.3 = Output : W4 Alias Portb.3
'przyciski
Config Pinc.0 = Input : Portc.0 = 1 : Prz1 Alias Pinc.0
Config Pinc.1 = Input : Portc.1 = 1 : Prz2 Alias Pinc.1
Config Pinc.2 = Input : Portc.2 = 1 : Enter Alias Pinc.2
Const Sw_mask = &B00000111 'maska przycisków (testowane tylko C0,C1 i C2)
Dim 5ms As Byte , Miliseconds As Byte , Helpb As Byte , Odliczanie As Byte
Dim S1 As Byte , M1 As Byte , Wyswietlacz As Byte , Tablica(4) As Byte
Dim Sw_licznik As Byte , Sw_stan As Byte , Lock As Byte
'timer dla 4x50Hz = 200Hz = 5ms
Config Timer0 = Timer , Prescale = 256
Load Timer0 , 155 '5ms @8MHz/256
On Timer0 Przerwanie : Enable Timer0
Enable Interrupts
Gosub Przelicz 'wpisz dane dla wyswietlaczy
Do
If 5ms = 1 Then
5ms = 0
Sw_stan = Pinc And Sw_mask 'sprawdź przyciski
If Sw_stan <> Sw_mask Then 'jesli któryś wciśnięty
If Sw_licznik < 80 Then 'policz co 5ms od 75 do 80 = 25ms
Incr Sw_licznik
Else
Sw_licznik = 50 'przyspiesz autoklik
Select Case Sw_stan 'sprawdź który przycisk
Case &B00000110 'plus
Gosub Dodawaj
Gosub Przelicz
Case &B00000101 'minus
Gosub Odejmuj
Gosub Przelicz
Case &B00000011 'enter
If Lock = 0 Then
Lock = 1 'zablokuj by nie wyłaczyć odliczania autoklikiem
If Odliczanie = 0 Then Odliczanie = 1 Else Odliczanie = 0
End If
Case &B00000100 'plus i minus razem
Odliczanie = 0 'zatrzymaj odlicznie jeśli uruchomione
M1 = 30 : S1 = 0 'wpisz 30min 00sec
Gosub Przelicz
End Select
End If
Else
Lock = 0
Sw_licznik = 75
End If
'tutaj liczenie do sekundy
If Miliseconds < 199 Then '200 x 5ms = 1000ms = 1s
Incr Miliseconds
Else
Miliseconds = 0
If Odliczanie = 1 Then 'jesli zezwolono odliczać
Gosub Odejmuj
Gosub Przelicz
End If
End If
End If
Loop
End
Dodawaj:
If M1 < 30 Then
Incr S1
If S1 > 59 Then
Incr M1
S1 = 0
End If
End If
Return
Odejmuj:
If S1 > 0 Then
Decr S1
Else
If M1 > 0 Then
Decr M1
S1 = 59
End If
End If
Return
Przelicz:
If M1 > 9 Then Helpb = M1 / 10 Else Helpb = 10
Tablica(1) = Lookup(helpb , Kody7seg)
If M1 > 0 Then
Helpb = M1 Mod 10
Tablica(2) = Lookup(helpb , Kody7seg)
Set Tablica(2).7
Else
Tablica(2) = 0
End If
Helpb = S1 / 10
Tablica(3) = Lookup(helpb , Kody7seg)
Helpb = S1 Mod 10
Tablica(4) = Lookup(helpb , Kody7seg)
Return
Przerwanie:
Load Timer0 , 155
If Wyswietlacz > 3 Then Wyswietlacz = 0
Portb = Portb Or &B00001111 'wylącz wszystkie wyświetlacze (0-3)
Segmenty = Tablica(wyswietlacz + 1) 'ustaw port wartością
Reset Portb.wyswietlacz 'włącz własciwy wyświetlacz
'Segmenty = Not Segmenty 'tylko dla mnie bo mam inne sterowanie wyświetlaczami
Incr Wyswietlacz
5ms = 1 'flaga - minęło 5 milisekund
Return
Kody7seg:
' *GFEDCBA
Data &B00111111 , &B00000110 , &B01011011 , &B01001111 , &B01100110 '---> 0 , 1 , 2 , 3 , 4
Data &B01101101 , &B01111101 , &B00000111 , &B01111111 , &B01101111 '---> 5 , 6 , 7 , 8 , 9
Data &B00000000 'pusty gasi zera wiodące

maxd89pl · Post autor: **maxd89pl** » 25 kwie 2017, 20:29

Nie no kolego bardzo ci dziękuje, ale jak i kiedy jesteś bardzo szybki, nie chciał bym wyjść na nie miłego ale ile czasu trzeba poświęcić by być takim profesjonalistą jak ty, ja nawet nie mam szkoły w tym kierunku.

Sprawdze jutro bo teraz to już do pracy sie szykuje.
Ja przy kubku kawy co najwyżej moge się podrapać po głowie heh

ad.
Kod działa wspaniale, ale nigdy nie widziałem takiej obsługi przycisków, więc postanowiłem go trochę przerobić i dodać dwu funkcyjność. Z tego co mi dałeś chyba nauczyłem się obsługi przycisków bez użycia waitms. Więc zrobiłem przyciski po swojemu i dodawanie działa super dodaje po 1 a po upływie 2,5sek ciągłego przyciskania dodaje 10. Zadowolony postępami zrobiłem tak samo odejmowanie ale jak zwykle coś musiałem sp... bo przy odejmowaniu w tej drugiej fazie czyli po 10 na wyświetlaczu od sekund w miejscu dziesiętnym pojawiają się niezdfiniowane liczby.

Wiesz może co ja tu nabroiłem:

Code: [Zaznacz cały] [Rozwiń/Zwiń]

$regfile = "m328pdef.dat"
$crystal = 8000000
$hwstack = 64
$swstack = 64
$framesize = 128
' PO WŁĄCZENIU PROGRAM WYŚWIETLA TYLKO DWA ZERA
' KIEDY WCIŚNIESZ RAZEM PLUS I MINUS TO ZEGAR USTAWI SIĘ NA
' 30min i 00sec
' KRÓTKIE WCIŚNIĘCIE ENTER URUCHAMIA BĄDŹ ZATRZYMUJE ODLICZANIE
' OCZYWIŚCIE MOŻNA SAMEMU USTAWIĆ ŻĄDANY CZAS PLUS/MINUS
Config Portd = Output : Portd = 255 : Segmenty Alias Portd
'anody wyswietlaczy
Config Portb.0 = Output : W1 Alias Portb.0
Config Portb.1 = Output : W2 Alias Portb.1
Config Portb.2 = Output : W3 Alias Portb.2
Config Portb.3 = Output : W4 Alias Portb.3
'przyciski
Config Pinc.0 = Input : Portc.0 = 1 : Prz1 Alias Pinc.0
Config Pinc.1 = Input : Portc.1 = 1 : Prz2 Alias Pinc.1
Config Pinc.2 = Input : Portc.2 = 1 : Enter Alias Pinc.2
Const Sw_mask = &B00000111 'maska przycisków (testowane tylko C0,C1 i C2)
Dim 5ms As Byte , Miliseconds As Byte , Helpb As Byte , Odliczanie As Byte
Dim S1 As Byte , M1 As Byte , Wyswietlacz As Byte , Tablica(4) As Byte
Dim Sw_licznikP As Byte , Sw_licznikM As Byte , Sw_stanP As Byte , Sw_stanM As Byte , Lock As Byte
'timer dla 4x50Hz = 200Hz = 5ms
Config Timer0 = Timer , Prescale = 256
Load Timer0 , 155 '5ms @8MHz/256
On Timer0 Przerwanie : Enable Timer0
Enable Interrupts
Gosub Przelicz 'wpisz dane dla wyswietlaczy
Do
If 5ms = 1 Then
5ms = 0
If Prz1 = 0 Then
incr Sw_licznikP
If Sw_licznikP = 25 Then
Sw_licznikP = 0
Incr Sw_stanP
Select Case Sw_stanP
Case 0 to 20 :
Gosub Dodawaj
Gosub Przelicz
Case 21 to 100 :
Gosub Dodawaj10
Gosub Przelicz
Sw_stanP = 21
End Select
End If
Else
Sw_stanP = 0
End if
If Prz2 = 0 Then
incr Sw_licznikM
If Sw_licznikM = 25 Then
Sw_licznikM = 0
Incr Sw_stanM
Select Case Sw_stanM
Case 0 to 20 :
Gosub Odejmuj
Gosub Przelicz
Case 21 to 100 :
Gosub Odejmuj10
Gosub Przelicz
Sw_stanM = 21
End Select
End If
Else
Sw_stanM = 0
End if
End if
'tutaj liczenie do sekundy
If Miliseconds < 199 Then '200 x 5ms = 1000ms = 1s
Incr Miliseconds
Else
Miliseconds = 0
If Odliczanie = 1 Then 'jesli zezwolono odliczać
Gosub Odejmuj
Gosub Przelicz
End If
End If
Loop
End
Dodawaj:
If M1 < 30 Then
Incr S1
If S1 > 59 Then
Incr M1
S1 = 0
End If
End If
Return
Dodawaj10:
If M1 < 30 Then
S1 = S1 + 10
If S1 > 59 Then
Incr M1
S1 = 0
End If
End If
Return
Odejmuj:
If S1 > 0 Then
Decr S1
Else
If M1 > 0 Then
Decr M1
S1 = 59
End If
End If
Return
Odejmuj10:
If S1 > 0 Then
S1 = S1 - 10
Else
If M1 > 0 Then
Decr M1
S1 = 59
End If
End If
Return
Przelicz:
If M1 > 9 Then Helpb = M1 / 10 Else Helpb = 10
Tablica(1) = Lookup(helpb , Kody7seg)
If M1 > 0 Then
Helpb = M1 Mod 10
Tablica(2) = Lookup(helpb , Kody7seg)
Set Tablica(2).7
Else
Tablica(2) = 0
End If
Helpb = S1 / 10
Tablica(3) = Lookup(helpb , Kody7seg)
Helpb = S1 Mod 10
Tablica(4) = Lookup(helpb , Kody7seg)
Return
Przerwanie:
Load Timer0 , 155
If Wyswietlacz > 3 Then Wyswietlacz = 0
Portb = Portb Or &B00001111 'wylącz wszystkie wyświetlacze (0-3)
Segmenty = Tablica(wyswietlacz + 1) 'ustaw port wartością
Reset Portb.wyswietlacz 'włącz własciwy wyświetlacz
'Segmenty = Not Segmenty 'tylko dla mnie bo mam inne sterowanie wyświetlaczami
Incr Wyswietlacz
5ms = 1 'flaga - minęło 5 milisekund
Return
Kody7seg:
' *GFEDCBA
Data &B00111111 , &B00000110 , &B01011011 , &B01001111 , &B01100110 '---> 0 , 1 , 2 , 3 , 4
Data &B01101101 , &B01111101 , &B00000111 , &B01111111 , &B01101111 '---> 5 , 6 , 7 , 8 , 9
Data &B00000000 'pusty gasi zera wiodące

niveasoft · Post autor: **niveasoft** » 26 kwie 2017, 19:47

Możesz dodać posta pod postem bo wtedy obserwujący temat dostają powiadomienia

Akurat założyłem ulubione słuchafony więc może gdzieś tu nonszalancko popełniam błąd, ale tak na luzie to sprawdź i popatrz czy taka logika się sprawdzi

Code: [Zaznacz cały] [Rozwiń/Zwiń]

Odejmuj10a:
If S1 > 10 Then 'jesli sekundy mają np.12
S1 = S1 - 10
Else 'jesli sekundy mają np.tylko 9
Helpb = 10 - S1 'zapamietaj że trzeba odjąć jeszcze 1
If M1 > 0 Then 'tylko jesli jest jeszcze z czego odejmować
Decr M1 'zmniejsz minuty
S1 = 59 - Helpb 'ustaw sekundy i odejmij zapamietaną resztę
Else
S1 = 0 ' jak juz nie ma z czego odejmować to napisz 0
End If
End If

Szczerze mówiąc łatwiej jest operować na jednej zmiennej typu Word.
Wtedy Minuty wyciągasz przez "Minuty = Zmienna /60" a Sekundy przez Sekundy = Zmienna Mod 60" czyli reszta z dzielenia przez 60 sekund bo to sa sekundy a nie całe minuty

Wtedy sobie możesz dodawać i odejmować co chcesz dopóki Zmienna > od tego co chcesz odjąć Else Zmienna = 0

A tak w ogóle to nie wpadłeś na pomysł że mozna automatycznie przyspieszać autoklik ?

On może na początku iść wolno i przyspieszać

Code: [Zaznacz cały] [Rozwiń/Zwiń]

If Sw_licznik < 75 Then Incr Sw_licznik 'przyspiesz autoklik

maxd89pl · Post autor: **maxd89pl** » 28 kwie 2017, 11:37

niveasoft pisze: ↑
26 kwie 2017, 19:47

Szczerze mówiąc łatwiej jest operować na jednej zmiennej typu Word.
Wtedy Minuty wyciągasz przez "Minuty = Zmienna /60" a Sekundy przez Sekundy = Zmienna Mod 60" czyli reszta z dzielenia przez 60 sekund bo to sa sekundy a nie całe minuty

Wtedy sobie możesz dodawać i odejmować co chcesz dopóki Zmienna > od tego co chcesz odjąć Else Zmienna = 0

A tak w ogóle to nie wpadłeś na pomysł że mozna automatycznie przyspieszać autoklik ?
On może na początku iść wolno i przyspieszać

Code: [Zaznacz cały] [Rozwiń/Zwiń]
If Sw_licznik < 75 Then Incr Sw_licznik 'przyspiesz autoklik

Heh pewnie masz racje, w sumie na pewno masz, tylko że ja muszę synchronizować atmegę z prockiem w mojej głowie

i takie operacje są dla mnie łatwiejsze do opanowania.

Nie było mnie parę dni, ale godzinami męczyłem ten kod, a nie chciałem tu pisać i męczyć z każdą pierdołą którą napotkam, ale jest, udało się i chodzi wszystko tak jak chce. Jestem bardzo zadowolony, gdyż to pierwszy mój program, który tak fajnie chodzi. Zawsze gdzieś miałem jakieś spowolnienia, albo przy przyciskach było trzeba czekać by zadziałał, czy tam klikać parę razy, a teraz wszystko pięknie, a to za sprawą wywalenia waitms-ów.
niveasoft - bardzo Ci chciałem podziękować za pomoc. Oraz chciałem się dopytać czy jak skończę całą naświetlarkę, czy mogę zamieścić tu gotowy, finalny projekt?

niveasoft · Post autor: **niveasoft** » 28 kwie 2017, 12:37

Oczywiście że możesz. Jest do tego wydzielony dział "Do It Yourself" - DIY- "Zrób to sam"

a to w celu odróżnienia gotowych projektów od tych nad którymi się jeszcze pracuje

Właściwie możesz się nim chwalić gdziekolwiek

Cieszę się że działa lepiej i widzisz plusy takiego rozwiązania.

Tak na marginesie to nie napisałeś czy procedura odejmowania 10 się sprawdziła

maxd89pl · Post autor: **maxd89pl** » 28 kwie 2017, 15:53

niveasoft pisze: ↑
28 kwie 2017, 12:37

Tak na marginesie to nie napisałeś czy procedura odejmowania 10 się sprawdziła

Tak działa pięknie i właśnie ją mam w programie, bardzo jeszcze raz dziękuje

Hehe teraz czas na wytrawiarke, wyswietlacz lcd 16x2 oled, duźa cyfry z twojego bloga i chyba encoder też z twojego bloga heh. Dawno temu robiłem wytrawiarke, wtedy zaczynałem się uczyć bascoma, po przenosinach z warsztatu gdziesz sie zawieruszyła heh jest film z tego okresu, sam zobacz jak ten program tam działał heh ledwo bo ledwo
[media] [/media]

niveasoft · Post autor: **niveasoft** » 28 kwie 2017, 16:33

Jak jesteśmy przy trawieniu i wyrobie płytek domowym sposobem to zerknij jak przerabiam laminator Tracer za 70zł żeby grzał do ~190 stopni.
Powyżej papier już brązowieje i przykleja się do płytek. Poniżej to efekt przeniesienia toneru nie jest gwarantowany a oryginalnie to ten laminator grzeje do 150 max.

Musze znaleźć do niego optymalne wartości dla PID, wtedy kod udostępnię. Może zaimplementuję selflearning.
Film pokazuje że przestrzela nieco te 180 do 200 , ale to kiedyś rozwiążę. Jak będzie mi to potrzebne

Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...

Re: Pomoc przy wyświetlaczach 7seg...